[clojure-emacs#117] Implement functions related to namespaces

Author: rrudakov

clojure-ts-mode.el

@@ -58,6 +58,7 @@
 (require 'treesit)
 (require 'align)
 (require 'subr-x)
+(require 'project)
 
 (declare-function treesit-parser-create "treesit.c")
 (declare-function treesit-node-eq "treesit.c")
@@ -266,6 +267,40 @@ values like this:
   :safe #'booleanp
   :type 'boolean)
 
+(defcustom clojure-ts-build-tool-files
+  '("project.clj"      ; Leiningen
+    "build.boot"       ; Boot
+    "build.gradle"     ; Gradle
+    "build.gradle.kts" ; Gradle
+    "deps.edn"         ; Clojure CLI (a.k.a. tools.deps)
+    "shadow-cljs.edn"  ; shadow-cljs
+    "bb.edn"           ; babashka
+    "nbb.edn"          ; nbb
+    "basilisp.edn"     ; Basilisp (Python)
+    )
+  "A list of files, which identify a Clojure project's root."
+  :type '(repeat string)
+  :package-version '(clojure-ts-mode . "0.6.0")
+  :safe (lambda (value)
+          (and (listp value)
+               (cl-every 'stringp value))))
+
+(defcustom clojure-ts-cache-project-dir t
+  "Whether to cache the results of `clojure-ts-project-dir'."
+  :type 'boolean
+  :safe #'booleanp
+  :package-version '(clojure-ts-mode . "0.6.0"))
+
+(defcustom clojure-ts-directory-prefixes
+  '("\\(?:src\\.\\)*clj[cdsx]*?\\.")
+  "A list of directory prefixes used by `clojure-expected-ns'.
+The prefixes are used to generate the correct namespace."
+  :type '(repeat string)
+  :package-version '(clojure-mode . "0.6.0")
+  :safe (lambda (value)
+          (and (listp value)
+               (cl-every 'stringp value))))
+
 (defvar clojure-ts-mode-remappings
   '((clojure-mode . clojure-ts-mode)
     (clojurescript-mode . clojure-ts-clojurescript-mode)
@@ -2689,6 +2724,57 @@ The command will prompt you to select one of the available sections."
     map)
   "Keymap for `clojure-ts-mode'.")
 
+;;; Project helpers
+
+(defun clojure-ts-project-root-path ()
+  "Return the absolute path to the project's root directory.
+
+Return nil if not inside of a project.
+
+NOTE: this function uses `project.el' internally, so if Clojure source
+is located in a non-Clojure project, but still under version control,
+the root of the project will be returned."
+  (let ((project-vc-extra-root-markers clojure-ts-build-tool-files))
+    (expand-file-name (project-root (project-current)))))
+
+(defvar-local clojure-ts-cached-project-dir nil
+  "A project dir cache used to speed up related operations.")
+
+(defun clojure-ts-project-dir ()
+  "Return an absolute path to the project's root directory."
+  (let ((project-dir (or clojure-ts-cached-project-dir
+                         (clojure-ts-project-root-path))))
+    (when (and clojure-ts-cache-project-dir
+               (derived-mode-p 'clojure-ts-mode)
+               (not clojure-ts-cached-project-dir))
+      (setq-local clojure-ts-cached-project-dir project-dir))
+    project-dir))
+
+(defun clojure-ts-project-relative-path (path)
+  "Denormalize PATH by making it relative to the project root."
+  (file-relative-name path (clojure-ts-project-dir)))
+
+;;; ns manipulation
+
+(defun clojure-ts-expected-ns (&optional path)
+  "Return the namespace matching PATH.
+
+PATH is expected to be an absolute file path.
+
+If PATH is nil, use the path to the file backing the current buffer."
+  (when-let* ((buf-file-name (buffer-file-name))
+              (path (or path (file-truename buf-file-name)))
+              (relative (thread-last path
+                                     (clojure-ts-project-relative-path)
+                                     (file-name-sans-extension)
+                                     (string-replace "_" "-")
+                                     (string-replace "/" "."))))
+    ;; Drop prefix from ns for projects with structure src/{clj,cljs,cljc}
+    (seq-reduce (lambda (acc regex)
+                  (replace-regexp-in-string regex "" acc))
+                clojure-ts-directory-prefixes
+                relative)))
+
 ;;; Completion
 
 (defconst clojure-ts--completion-query-defuns

test/samples/deps-project/deps.edn

@@ -0,0 +1 @@
+{:paths ["src/clj"]}

test/samples/deps-project/src/clj/hello-clj/world.clj

@@ -0,0 +1 @@
+(ns hello-clj.world)

test/samples/deps-project/src/clj/hello/world.clj

@@ -0,0 +1 @@
+(ns hello.world)

test/samples/refactoring.clj

@@ -146,4 +146,4 @@
   clojure.lang.IPersistentMap
   (set-parameter [])
   (set-parameter [m ^PreparedStatement s i]
-    (.setObject| s i (->pgobject m))))
+    (.setObject s i (->pgobject m))))