Linking errors

[AlexiyOrlov]

I downloaded imgui_impl_glfw and imgui_impl_vulkan files, placed them in 'headers' directory and made this Cmake file:

cmake_minimum_required(VERSION 3.15)
project(BlockyCubes)

# Set C++ standard
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

# Add include and source directories
file(GLOB HEADERS
	${PROJECT_SOURCE_DIR}/headers/*.h
)

# Collect all source files
file(GLOB_RECURSE SOURCES 
	${PROJECT_SOURCE_DIR}/source/*.cpp
)

include_directories(
	${PROJECT_SOURCE_DIR}/headers
)

# Create executable
add_executable(BlockyCubes ${HEADERS} ${SOURCES})

FILE(COPY shaders/compile.bat shaders/shader.frag shaders/shader.vert DESTINATION ${CMAKE_BINARY_DIR}/shaders)
FILE(COPY textures/ground.png DESTINATION ${CMAKE_BINARY_DIR}/textures)

When try running the project, I get errors:

[PathogenDavid]

placed them in 'headers' directory

Make sure you also put the .cpp files in your source directory.

---

As an aside, it's not recommended to use GLOB to enumerate your source files as CMake will not scan for new files automatically. (See the note in the CMake documentation)

In fact if you did already add the files to source, you might just need to manually re-run CMake to regenerate your project files.

[erikbjur]

Here's how I do it. No clue if this is the "Right" way but I add Dear ImGUI as a submodule. Then build the library as a static library using CMake.
Here's where I clone the ImGui repo:
Project_Root/External_Libraries/ImGui/imgui
Then I add the static library CMakeLists.txt file here:
Project_Root/External_Libraries/ImGui/CMakeLists.txt

Here below is each section of the static library CMakeLists.txt file. First define the project name.

project( ImGuiLibrary )

Manually add all of the source files

set(LibrarySources
imgui/imgui.cpp
imgui/imgui_widgets.cpp
imgui/imgui_tables.cpp
imgui/imgui_draw.cpp
imgui/misc/cpp/imgui_stdlib.cpp
imgui/backends/imgui_impl_glfw.cpp
imgui/backends/imgui_impl_opengl3.cpp
)

Set the name of the ImGui library to imgui

set(LibraryName imgui)

Set an output directory location

set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${OutputDir}/${PROJECT_NAME}/static_libs )

Build the library with the source files above

add_library( ${LibraryName} STATIC ${LibrarySources} )

Link the GLFW library into ImGui

find_package(OpenGL REQUIRED)
target_link_libraries( ${LibraryName} PUBLIC glfw OpenGL::GL )

Here's the include directories needed by anyone else using the imgui library

target_include_directories( ${LibraryName} PUBLIC imgui )
target_include_directories( ${LibraryName} PUBLIC imgui/misc/cpp )
target_include_directories( ${LibraryName} PUBLIC imgui/backends )

Then in your application CMakeLists.txt file where you will link against this static library add this line near the bottom:

target_link_libraries( ${PROJECT_NAME} imgui )