Implement electric characters

This defines various keys that will trigger auto reindentation when
appropriate. This approach is similar to how `cc-mode' implements
electric keys.

Hooks are added to ensure that, unless customized otherwise,
`haskell-indentation-electric-flag' will be updated along with the value
of `electric-indent-mode' in the buffer.

Closes #1133.

Author: fice-t

haskell-indentation.el

@@ -74,10 +74,23 @@
   :type 'integer
   :group 'haskell-indentation)
 
-(defconst haskell-indentation-mode-map
+(defcustom haskell-indentation-electric-flag nil
+  "Non-nil means insertion of some characters may auto reindent the line.
+This value is set to the value of the variable `electric-indent-mode'
+unless it is set to 'always."
+  :type 'symbol
+  :group 'haskell-indentation)
+(make-variable-buffer-local 'haskell-indentation-electric-flag)
+
+(defvar haskell-indentation-mode-map
   (let ((map (make-sparse-keymap)))
-    (define-key map (kbd "RET") 'haskell-indentation-newline-and-indent)
-    (define-key map (kbd "<backtab>") 'haskell-indentation-indent-backwards)
+    (define-key map (kbd "RET") #'haskell-indentation-newline-and-indent)
+    (define-key map (kbd "<backtab>") #'haskell-indentation-indent-backwards)
+    (define-key map (kbd ",") #'haskell-indentation-common-electric-command)
+    (define-key map (kbd ";") #'haskell-indentation-common-electric-command)
+    (define-key map (kbd ")") #'haskell-indentation-common-electric-command)
+    (define-key map (kbd "}") #'haskell-indentation-common-electric-command)
+    (define-key map (kbd "]") #'haskell-indentation-common-electric-command)
     map)
   "Keymap for `haskell-indentation-mode'.")
 
@@ -87,18 +100,25 @@
 It rebinds RET, DEL and BACKSPACE, so that indentations can be
 set and deleted as if they were real tabs."
   :keymap haskell-indentation-mode-map
-  (kill-local-variable 'indent-line-function)
-  (kill-local-variable 'indent-region-function)
 
   (when haskell-indentation-mode
     (when (and (bound-and-true-p haskell-indent-mode)
                (fboundp 'turn-off-haskell-indent))
       (turn-off-haskell-indent))
-    (when (and (bound-and-true-p haskell-simple-indent-mode)
-               (fboundp 'haskell-simple-indent-mode))
-      (haskell-simple-indent-mode 0))
-    (setq-local indent-line-function 'haskell-indentation-indent-line)
-    (setq-local indent-region-function 'haskell-indentation-indent-region)))
+    (setq-local indent-line-function #'haskell-indentation-indent-line)
+    (setq-local indent-region-function #'haskell-indentation-indent-region)
+
+    ;; 24.3 doesn't have this mode or the hooks
+    (when (fboundp 'electric-indent-local-mode)
+      (haskell-indentation-electric-hook)
+      (add-hook 'electric-indent-mode-hook
+                #'haskell-indentation-electric-hook
+                nil
+                t)
+      (add-hook 'electric-indent-local-mode-hook
+                #'haskell-indentation-electric-local-hook
+                nil
+                t))))
 
 ;;;###autoload
 (defun turn-on-haskell-indentation ()
@@ -135,7 +155,7 @@ set and deleted as if they were real tabs."
 Called from a program, takes three arguments, START, END and ARG.
 You can remove all indentation from a region by giving a large
 negative ARG.  Handles bird style literate Haskell too."
-  (interactive "r\np")
+  (interactive "*r\np")
   (save-excursion
     (goto-char end)
     (let ((end-marker (point-marker)))
@@ -171,7 +191,7 @@ negative ARG.  Handles bird style literate Haskell too."
 
 (defun haskell-indentation-newline-and-indent ()
   "Insert newline and indent."
-  (interactive)
+  (interactive "*")
   ;; On RET (or C-j), we:
   ;;   - just jump to the next line if literate haskell, but outside code
   (if (haskell-indentation-bird-outside-code-p)
@@ -224,7 +244,7 @@ Do nothing inside multiline comments and multiline strings.
 Start enumerating the indentation points to the right.  The user
 can continue by repeatedly pressing TAB.  When there is no more
 indentation points to the right, we switch going to the left."
-  (interactive)
+  (interactive "*")
   ;; try to repeat
   (when (not (haskell-indentation-indent-line-repeat))
     (setq haskell-indentation-dyn-last-direction nil)
@@ -296,7 +316,7 @@ fixes up only indentation."
 
 (defun haskell-indentation-indent-backwards ()
   "Indent the current line to the previous indentation point."
-  (interactive)
+  (interactive "*")
   (cond
    ((and (memq last-command
                '(indent-for-tab-command haskell-indentation-indent-backwards))
@@ -323,7 +343,42 @@ fixes up only indentation."
            (car (haskell-indentation-first-indentation)) cursor-in-whitespace)
         (haskell-indentation-reindent-to pi cursor-in-whitespace))))))
 
-
+(defun haskell-indentation-common-electric-command (arg)
+  "Call `self-insert-command' to insert the character typed ARG times
+and indent when all of the following are true:
+
+1) The character is the first non-whitespace character on the line.
+2) There is only one possible indentation position.
+3) The variable `haskell-use-electric-keys' is non-nil.
+4) The point is not in a comment, string, or quasiquote."
+  (interactive "*p")
+  (let* ((col (haskell-indentation-current-indentation))
+         (at-indent? (= col (current-column)))
+         ind)
+    (self-insert-command arg)
+    (when (and at-indent?
+               haskell-indentation-electric-flag
+               (> arg 0)
+               (not (nth 8 (syntax-ppss)))
+               (= 1 (save-excursion
+                      (move-to-column col)
+                      (length (setq ind (haskell-indentation-find-indentations))))))
+      (haskell-indentation-reindent-to (car ind)))))
+
+(defun haskell-indentation-electric-hook ()
+  "Update `haskell-indentation-electric-flag' in all Haskell buffers."
+  (mapc (lambda (buf)
+          (with-current-buffer buf
+            (when (eq major-mode 'haskell-mode)
+              (haskell-indentation-electric-local-hook))))
+        (buffer-list)))
+
+(defun haskell-indentation-electric-local-hook ()
+  "Update `haskell-indentation-electric-flag' unless its value is 'always."
+  (unless (eq haskell-indentation-electric-flag 'always)
+    (setq haskell-indentation-electric-flag electric-indent-mode)))
+
+
 ;;----------------------------------------------------------------------------
 ;; Parser Starts Here
 
@@ -740,8 +795,7 @@ For example
          (throw 'parse-end nil))))))
 
 (defun haskell-indentation-toplevel-where ()
-  "Parse 'where' that we may hit as a standalone in module
-declaration."
+  "Parse 'where' that we may hit as a standalone in module declaration."
   (haskell-indentation-read-next-token)
 
   (when (eq current-token 'end-tokens)