build/CI/packaging: modernize autotools files

Fix warnings about obsolete/deprecated features reported by modern
autotools. Also updates third-party m4 macros.

Author: akopytov

configure.ac

@@ -1,8 +1,7 @@
 # Process this file with autoconf to produce a configure script.
 
-AC_PREREQ(2.63)
-AC_INIT([sysbench],[1.1.0],[https://github.com/akopytov/sysbench/issues],
-        [sysbench], [https://github.com/akopytov/sysbench])
+AC_PREREQ([2.72])
+AC_INIT([sysbench],[1.1.0],[https://github.com/akopytov/sysbench/issues],[sysbench],[https://github.com/akopytov/sysbench])
 AC_CONFIG_AUX_DIR([config])
 
 # Define m4_ifblank and m4_ifnblank macros from introduced in
@@ -31,7 +30,7 @@ CXXFLAGS=${SAVE_CXXFLAGS}
 
 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
 AC_CONFIG_SRCDIR([src/sysbench.c])
-AC_CONFIG_HEADER([config/config.h])
+AC_CONFIG_HEADERS([config/config.h])
 AC_CONFIG_MACRO_DIR([m4])
 
 m4_pattern_forbid([^PKG_[A-Z_]+$],
@@ -40,7 +39,6 @@ m4_pattern_forbid([^PKG_[A-Z_]+$],
 ACX_USE_SYSTEM_EXTENSIONS
 
 AC_PROG_CC
-AC_PROG_CC_C99
 AC_PROG_CPP
 AM_PROG_CC_C_O
 
@@ -58,7 +56,7 @@ AS_CASE([$CFLAGS],
 
 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
 
-AC_PROG_LIBTOOL
+LT_INIT
 
 AC_CHECK_PROG(sb_have_pkg_config, pkg-config, yes, no)
 if test x"$sb_have_pkg_config" = xno; then
@@ -199,9 +197,6 @@ AC_SUBST([USE_PGSQL])
 AC_CHECK_AIO
 AM_CONDITIONAL(USE_AIO, test x$enable_aio = xyes)
 
-# Checks for header files.
-AC_HEADER_STDC
-
 AC_CHECK_HEADERS([ \
 errno.h \
 fcntl.h \
@@ -225,7 +220,7 @@ libgen.h \
 
 # Checks for typedefs, structures, and compiler characteristics.
 AC_TYPE_OFF_T
-AC_HEADER_TIME
+
 AX_TLS([],
   AC_MSG_ERROR([thread-local storage is not suppored by the target platform!])
 )

m4/ac_check_pgsql.m4

@@ -10,7 +10,7 @@ AC_DEFUN([AC_CHECK_PGSQL],[
 if test [ -z "$ac_cv_pgsql_includes" ] 
 then 
     AC_ARG_WITH([pgsql-includes], 
-                AC_HELP_STRING([--with-pgsql-includes], [path to PostgreSQL header files]),
+                AS_HELP_STRING([--with-pgsql-includes], [path to PostgreSQL header files]),
                 [ac_cv_pgsql_includes=$withval])
 fi
 if test [ -n "$ac_cv_pgsql_includes" ]
@@ -24,7 +24,7 @@ fi
 if test [ -z "$ac_cv_pgsql_libs" ]
 then
     AC_ARG_WITH([pgsql-libs], 
-                AC_HELP_STRING([--with-pgsql-libs], [path to PostgreSQL libraries]),
+                AS_HELP_STRING([--with-pgsql-libs], [path to PostgreSQL libraries]),
                 [ac_cv_pgsql_libs=$withval])
 fi
 

m4/ax_tls.m4

@@ -44,31 +44,28 @@
 #   modified version of the Autoconf Macro, you may extend this special
 #   exception to the GPL to apply to your modified version as well.
 
-#serial 14
+#serial 15
 
 AC_DEFUN([AX_TLS], [
   AC_MSG_CHECKING([for thread local storage (TLS) class])
   AC_CACHE_VAL([ac_cv_tls],
    [for ax_tls_keyword in thread_local _Thread_local __thread '__declspec(thread)' none; do
        AS_CASE([$ax_tls_keyword],
           [none], [ac_cv_tls=none ; break],
-          [AC_TRY_COMPILE(
-              [#include <stdlib.h>
-               static void
-               foo(void) {
-               static ] $ax_tls_keyword [ int bar;
-               exit(1);
-               }],
-               [],
-               [ac_cv_tls=$ax_tls_keyword ; break],
-               ac_cv_tls=none
-           )])
-    done
-  ])
+          [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
+              [#include <stdlib.h>],
+              [static  $ax_tls_keyword  int bar;]
+            )],
+            [ac_cv_tls=$ax_tls_keyword ; break],
+            [ac_cv_tls=none]
+          )]
+        )
+    done ]
+  )
   AC_MSG_RESULT([$ac_cv_tls])
 
   AS_IF([test "$ac_cv_tls" != "none"],
-    [AC_DEFINE_UNQUOTED([TLS],[$ac_cv_tls],[If the compiler supports a TLS storage class define it to that here])
-     m4_ifnblank([$1],[$1])],
-    [m4_ifnblank([$2],[$2])])
+    [AC_DEFINE_UNQUOTED([TLS],[$ac_cv_tls],[If the compiler supports a TLS storage class, define it to that here])
+     m4_ifnblank([$1],[$1],[[:]])],
+    [m4_ifnblank([$2],[$2],[[:]])])
 ])